Algoritmo para calcular as operações de arranjo ou combinação usando função ou procedimento.

Crie um programa que calcule as operações de combinação e arranjo conforme escolha do usuário.
A n,p =   n!
             (n-p)!
algoritmo "arranjoCombinacao"
funcao FATORIAL(NUM:inteiro):inteiro
var
   cont,fat:inteiro
inicio
      fat<-1
      se(NUM > 0)entao
         para cont de 1 ate NUM passo 1 faca
              fat<-fat*cont
         fimpara
      fimse
      retorne fat
fimfuncao
var
   op,n1,n2:inteiro
inicio
      repita
            escreva("Qual combinação deseja utilizar 1-combinação 2-arranjo 0-sair")
            leia(op)

            escolha(op)
                caso 1
                     escreval("Informe dois valoes para calcular a combinação")
                     leia(n1,n2)
                     escreva("A combinacao eh: ",FATORIAL(n1)/(FATORIAL(n2)*FATORIAL(n1-n2)))
                caso 2
                     escreval("Informe dois valoes para calcular o Arranjo")
                     leia(n1,n2)
                     escreva("O valor do arranjo eh: ",FATORIAL(n1)/FATORIAL(n1-n2))
                caso 0
                    escreval("saindo...")
                outrocaso
                         escreval("opção inválida ")
            fimescolha
      ate op = 0
fimalgoritmo

Usando procedimento

algoritmo "arranjoCombinacao"
procedimento ARRANJO(N,P:inteiro)
var
   cont,a1,a2:inteiro
   arran:real
inicio
      a1<-1
      a2<- 1
      se(N> 0)entao
         para cont de 1 ate N passo 1 faca
            a1<-a1*cont
         fimpara
      fimse
      se((N-P)>0)entao
          para cont de 1 ate (N-P) passo 1 faca
            a2<-a2*cont
         fimpara
      fimse
      arran<-a1/a2
      escreva("O valor do arranjo eh: ",arran)
fimprocedimento

procedimento COMBINACAO(N,P:inteiro)
var
   cont,c1,c2,c3:inteiro
   comb:real
inicio
      c1<-1
      c2<-1
      c3<-1
      se(N> 0)entao
         para cont de 1 ate N passo 1 faca
            c1<-c1*cont
         fimpara
      fimse
      se((P)>0)entao
          para cont de 1 ate P passo 1 faca
            c2<-c2*cont
         fimpara
      fimse
      se((N-P)>0)entao
          para cont de 1 ate (N-P) passo 1 faca
            c3<-c3*cont
         fimpara
      fimse
      comb<-c1/(c2*c3)
      escreva("A combinacao eh: ",comb)
fimprocedimento
var
   op,n1,n2:inteiro
inicio
      repita
            escreva("Qual combinação deseja utilizar 1-combinação 2-arranjo 0-sair")
            leia(op)
            
            escolha(op)
                caso 1
                     escreval("Informe dois valoes para calcular a combinação")
                     leia(n1,n2)
                     COMBINACAO(n1,n2)
                caso 2
                     escreval("Informe dois valoes para calcular o Arranjo")
                     leia(n1,n2)
                     ARRANJO(n1,n2)
                caso 0
                    escreval("saindo...")
                
                outrocaso
                         escreval("opção inválida ")
            fimescolha
      ate op = 0
fimalgoritmo

Duvidas ou Trabalhos para fazer entre em Contato: Email: marcofernando71@gmail.com